Forum libero

"libraries"

    hmi/conout;
    math/random;
    utils/msecs24;

"directors"

    unit = 32;
    display status = engage;

"constants"

    k = 20 000 000;    (di elementi)

"variables"

    t filling source range = { filling_source_range...\lf } : 8;
    t filling lookup table = { filling_lookup_table...\lf } : 8;
    t testing integer maths = { testing_integer_maths...\lf } : 8;
    t testing lookups = { testing_lookups...\lf } : 8;
    t elapsed maths time = { elapsed_maths_time:_ } : 8;
    t elapsed lookups time = { elapsed_lookups_time:_ } : 8;
    t lf = { \lf } : 8;

"workspace"

    r source * k;
    r target * k;
    r lookup * [65536 multiplied 16] as bit size;    (65536 valori di 16 bit)

    n start time;
    n stop time;

"programme"

    mt . sgenrand: 12345;

    conout . t say: t filling source range;

        a # a;
        b = k;
        
        "filling source range"

            [r source [a]] <- mt . i rnd;
            [r source [a]] & ffffh;

            + a;

        ? b ^ filling source range;

    conout . t say: t filling lookup table;

        a # a;
        b # b;
        c = 65536 div 2;

        "filling lookup table"

            as,

                d = a;
                d / 25;

            [r lookup [b]] = d;

            + a;

            as,

                d = a;
                d / 25;
            @    d < 16;
            
            [r lookup [b]] | d;

            + a;
            + b;

        ? c ^ filling lookup table;

    conout . t say: t testing integer maths;

    [n start time] <- msecs 24;

        a # a;
        b = k;

        "testing integer maths"

            as,

                c = [r source [a]];
                c / 25;

            [r target [a]] = c;

            + a;

        ? b ^ testing integer maths;

    [n stop time] <- msecs 24;
    [n stop time] - [n start time];

    conout . t say: t elapsed maths time;
    conout . n say: [n stop time];
    conout . t say: t lf;

    conout . t say: t testing lookups;

    [n start time] <- msecs 24;

        a # a;
        b = k;

        "testing lookups"

            as,

                c = [r source [a]];
                d = c;

            '    d > 1;
                c & 1;

            @    c < 4;
                e = [r lookup [d]];
                
            @    e > c;
                + a;

                e & ffffh;
                - b;

            [r target [a minus 1]] = e;

        ? b ! zero > testing lookups;

    [n stop time] <- msecs 24;
    [n stop time] - [n start time];

    conout . t say: t elapsed lookups time;
    conout . n say: [n stop time];
    conout . t say: t lf;

    as,

        [thread command] = suspend thread;
        [thread suspend timeout] = 10 000 (milliseconds);

    isocall;

    end;

filling source range...
filling lookup table...
testing integer maths...
elapsed maths time: 109
testing lookups...
elapsed lookups time: 47